@import <Foundation/CPObject.j>

// will hold our images
var starEmpty, starSet, starActive;

@implementation StarRater : CPView
{
  int _value;          // the number of selected stars
  int _hoverStars;     // the number of stars where the mouse hovers
  CPView _starFrame;   // displays the selected stars
  CPView _hoverFrame;  // displays the stars when the mouse hovers over the control
  id _delegate;        // a callback to update when the stars changed
}
+ (void)initialize
{
  starEmpty  = [[CPImage alloc] initWithContentsOfFile: "Resources/StarRater/empty.gif" size: CPSizeMake(25, 25)];
  starSet    = [[CPImage alloc] initWithContentsOfFile: "Resources/StarRater/set.gif" size: CPSizeMake(25, 25)];
  starActive = [[CPImage alloc] initWithContentsOfFile: "Resources/StarRater/active.gif" size: CPSizeMake(25, 25)];
}
- (id)initWithFrame:(CPRect)frame
{
  self = [super initWithFrame: frame];
  // FIXME: set the mousepointer
  self._DOMElement.style.cursor = "pointer";
  // set our background to a pattern of the empty star image
  [self setBackgroundColor:[CPColor colorWithPatternImage:starEmpty]];

  // set the initial values for our control
  _value = 0;
  _hoverStars = 0;

  // construct the Frames
  _starFrame = [[CPView alloc] initWithFrame:[self bounds]];
  [_starFrame setBackgroundColor:[CPColor colorWithPatternImage:starSet]];

  _hoverFrame = [[CPView alloc] initWithFrame:[self bounds]];
  [_hoverFrame setBackgroundColor:[CPColor colorWithPatternImage:starActive]];

  // set the size star and hover frame. (both to 0 width)
  [self _redraw];
  [self _redrawHover];

  [self addSubview: _starFrame];
  [self addSubview: _hoverFrame];
  return self;
}

// setter and getter for the delegate
- (void)setDelegate:(id)aDelegate
{
  if (_delegate == aDelegate)
    return;
  _delegate = aDelegate;
  [self _update];
}

- (id)delegate
{
  return _delegate;
}

// setter and getter for the value
- (void)setValue:(int)value
{
  if(_value == value)
    return;
  _value = value;
  // if the value was set,
  // we want to update the delegate a notification
  // and redraw our frames accordingly.
  [self _update];
  [self _redraw];
}

- (int)intValue
{
  return _value;
}

// inform the delegate about the current value.
- (void)_update
{
  if(_delegate && [_delegate respondsToSelector:@selector(updateWithIntValue:)])
    [_delegate updateWithIntValue:_value];
}

// notify the delegate about temporary (hover) changes
- (void)_updateTemporary
{
  if(_delegate && [_delegate respondsToSelector:@selector(updateTemporaryWithIntValue:)])
    [_delegate updateTemporaryWithIntValue:_hoverStars];
}

// redraw our child frames.
- (void)_redraw
{
  [_starFrame setFrameSize:CPSizeMake(_value * 25, 25)];
}

- (void)_redrawHover
{
  [_hoverFrame setFrameSize:CPSizeMake(_hoverStars * 25, 25)];
}

// mouse movement handler
- (void)mouseDown:(CPEvent)anEvent
{
  // compute the offset relative to this frame
  var offset = [self convertPoint:[anEvent locationInWindow] fromView:nil].x
  // set a left threshold. If we click less then 5px, we won't select a star.
  if(offset < 5) [self setValue:0];
  // otherwise we set our value
  else [self setValue:Math.ceil(offset/25)];
  // setting hoverStars to 0 and redrawing them gives
  // a visual feedback about the change.
  _hoverStars = 0;
  [self _redraw];
  [self _redrawHover];
}

// when the mouse enters or left the view,
// we want to reset the visual hover aid.
- (void)mouseEntered:(CPEvent)anEvent
{
  _hoverStars = 0;
  [self _update];
  [self _redrawHover];
}
- (void)mouseExited:(CPEvent)anEvent
{
  _hoverStars = 0;
  [self _update];
  [self _redrawHover];
}

// on mouse move, we construct a visual hovering effect.     
- (void)mouseMoved:(CPEvent)anEvent
{
  var offset = [self convertPoint:[anEvent locationInWindow] fromView:nil].x
  if(offset < 5) starValue = 0;
  else starValue = Math.ceil(offset/25);
  if(starValue == _hoverStars) return;
  _hoverStars = starValue;
  [self _updateTemporary];
  [self _redrawHover];
}
@end

@import <Foundation/CPObject.j>

@implementation ActiveTextField : CPTextField
{
  var _values; 
}
- (id)initWithFrame:(CPRect)aFrame
{
  self = [super initWithFrame:aFrame];
  // initialize the values we want to display
  _values = [ @"No selection",
              @"Failed",
              @"Not good",
              @"Average",
              @"Good",
              @"Very good",
              @"Excellent" ];
  return self;
}
- (void) updateTemporaryWithIntValue:(int)value
{
  [self updateWithIntValue:value];
}
- (void) updateWithIntValue:(int)value
{
  [self setStringValue:_values[value]];  
}
@end

@import <Foundation/CPObject.j>
@import "StarRater.j"
@import "ActiveTextField.j"

@implementation StarRaterView : CPView
{
  CPView _rater;
}
- (id)initWithFrame:(CPRect)aFrame
{
  self = [super initWithFrame:aFrame];
  // setup the rater and the indicator
  _rater = [[StarRater alloc] initWithFrame:CGRectMake(0, 0, 6 * 25, 25)];
  var indicator  = [[ActiveTextField alloc] initWithFrame:CGRectMakeZero()];
  // let the indicator compute it's size.
  [indicator sizeToFit];
  // get the height of the indicator to vertical align it with the rater
  var height = CGRectGetHeight([indicator frame]);
  [indicator setFrameOrigin:CGPointMake(CGRectGetMaxX([_rater frame]) + 10, (25-height)/2.0)];
  // set the width of the indicator so that it can hold all labels.
  [indicator setFrameSize:CGSizeMake(100,height)];
  [_rater setDelegate:indicator];
  [self addSubview:_rater];
  [self addSubview:indicator];
  return self;
}
@end

- (void)applicationDidFinishLaunching:(CPNotification)aNotification
{
  var theWindow = [[CPWindow alloc] initWithContentRect:CGRectMakeZero() styleMask:CPBorderlessBridgeWindowMask],
    contentView = [theWindow contentView];

  // capture Mouse move events
  [theWindow setAcceptsMouseMovedEvents:YES];

  // use our custom control
  var rater = [[StarRaterView alloc] initWithFrame:CGRectMakeZero()];
  [rater setFrameSize:CGSizeMake(250,25)];
  [rater setAutoresizingMask:CPViewMinXMargin | CPViewMaxXMargin | CPViewMinYMargin | CPViewMaxYMargin];
  [rater setFrameOrigin:CGPointMake((CGRectGetWidth([contentView bounds])
                                     - CGRectGetWidth([rater frame])) / 2.0,
                                    (CGRectGetHeight([contentView bounds])
                                     - CGRectGetHeight([rater frame])) / 2.0)];
  // add our rater to the window
  [contentView addSubview:rater];
  [theWindow orderFront:self];
}